using terms from application "Mail"
     on perform mail action with messages selectedMsgs
          
          -- scegliamo il colore
          set coloreScelto to item 1 of (choose from list {"Blu", "Grigio", "Verde", "Arancione", "Viola", "Rosso", "Giallo", "Nessuno"})
          if coloreScelto is equal to "Blu" then
               set colore to blue
          else if coloreScelto is equal to "Grigio" then
               set colore to gray
          else if coloreScelto is equal to "Verde" then
               set colore to green
          else if coloreScelto is equal to "Arancione" then
               set colore to orange
          else if coloreScelto is equal to "Viola" then
               set colore to purple
          else if coloreScelto is equal to "Rosso" then
               set colore to red
          else if coloreScelto is equal to "Giallo" then
               set colore to yellow
          else if coloreScelto is equal to "Nessuno" then
               set colore to none
          end if
          
          tell application "Mail"
               set selCount to (count of selectedMsgs)
               if selCount is equal to 0 then
                    display dialog "Non ci sono messaggi selezionati!" buttons {"OK"} default button 1 with icon stop
               else
                    repeat with counter from 1 to selCount
                         set msg to item counter of selectedMsgs
                         -- applichiamo il colore
                         set background color of msg to colore
                    end repeat
               end if
          end tell
     end perform mail action with messages
end using terms from

-- If run as an ordinary script, instead of directly from the Scripts
-- menu, it will call the default handler instead.
using terms from application "Mail"
     on run
          tell application "Mail" to set sel to selection
          tell me to perform mail action with messages (sel)
     end run
end using terms from

using terms from application "Mail"
     on perform mail action with messages selectedMsgs
          tell application "Mail"
               set selCount to (count of selectedMsgs)
               if selCount is equal to 0 then
                    display dialog "Non ci sono messaggi selezionati!" buttons {"OK"} default button 1 with icon stop
               else
                    -- scegliamo il colore
                    set colore to my scegliColore()
                    
                    if colore is not false then
                         repeat with counter from 1 to selCount
                              set msg to item counter of selectedMsgs
                              -- applichiamo il colore
                              set background color of msg to colore
                         end repeat
                    end if
               end if
          end tell
     end perform mail action with messages
     
     -- If run as an ordinary script, instead of directly from the Scripts
     -- menu, it will call the default handler instead.
     on run
          tell application "Mail" to set sel to selection
          tell me to perform mail action with messages (sel)
     end run
     
     -- Sceglie il colore dell'etichetta e lo restituisce trasformato da stringa a colore interno di Mail
     -- Se non ne viene selezionato nessuno, restituisce false
     on scegliColore()
          set listaColori to {"Blu", "Grigio", "Verde", "Arancione", "Viola", "Rosso", "Giallo", "Nessuno"}
          set coloreScelto to choose from list listaColori with title "Etichettatore" with prompt "Scegli il colore dell'etichetta" without multiple selections allowed and empty selection allowed
          if coloreScelto is equal to false then
               return false
          end if
          set coloreScelto to the item 1 of coloreScelto
          if coloreScelto is equal to "Blu" then
               return blue
          else if coloreScelto is equal to "Grigio" then
               return gray
          else if coloreScelto is equal to "Verde" then
               return green
          else if coloreScelto is equal to "Arancione" then
               return orange
          else if coloreScelto is equal to "Viola" then
               return purple
          else if coloreScelto is equal to "Rosso" then
               return red
          else if coloreScelto is equal to "Giallo" then
               return yellow
          else if coloreScelto is equal to "Nessuno" then
               return none
          end if
     end scegliColore
end using terms from

questo script vale un altro newton

ma va anche/ancora con Mail.app 3.2 (919/919.2) in dotazione con Leoponz ???

se si sempre nello stesso path va installato ? Grazie!

Sì, tutto uguale.

Ciao
Paolo