set trovato to 0

tell application "Skim"
    set doc to (get front document)
    set nomefile to (name of doc)
end tell

tell application "BibDesk"
    tell document 1
        set pubblicazioni to (get publications)
        repeat with pub in pubblicazioni
            set percorso to (local file of pub)
            if percorso is equal to "" then
                set percorso to (get value of field "local-url" of pub)
            end if
            set nome to my GetFileName(percorso)
            if nome is equal to nomefile then
                show pub
                set trovato to 1
                exit repeat
            end if
        end repeat
    end tell
end tell

if trovato is equal to 1 then
    tell application "BibDesk" to activate
else
    tell application "Skim" to (display dialog "Unable to find this paper in BibDesk!" buttons {"OK"} default button 1)
end if

on GetFileName(percorso)
    set old_delimiters to text item delimiters
    set text item delimiters to "/"
    set elementi to (get text items of percorso)
    set text item delimiters to old_delimiters
    return last item of elementi
end GetFileName