Mail/Find Accounts in Mail (fromApplication: Mail)
Address Book/Group Mailer (salutationText: Dear, includeGreeting: true, sendMessages: false, recipientStyle: 0)
Address Book/Filter People in Address Book (fromApplication: Address Book)
Address Book/Find People with Birthdays (dateRange: 0)

tell application "Automator"
    set info to my getWorkflowInfo(document 1)
    return my formatWorkflowInfo(info)
end tell

to formatWorkflowInfo(info)
    set output to {}
    repeat with action in info
        set oneline to action's application & "/" & action's name
        if (count of action's params) is not 0 then
            set oneline to oneline & " ("
            set paramslist to {}
            repeat with i from 1 to count of action's params
                set param to item i of action's params
                set end of paramslist to param's |name| & ": " & param's value
            end repeat
            set oneline to oneline & join(", ", paramslist)
            set oneline to oneline & ")"
        end if
        
        
        set end of output to oneline
    end repeat
    return join(return, output)
end formatWorkflowInfo

to getWorkflowInfo(wflow)
    tell application "Automator"
        tell wflow
            set acts to Automator actions
            
            set ll to {}
            
            repeat with act in acts
                
                
                set actInfo to {application:"", name:"", params:{}}
                set actInfo's application to (item 1 of (act's target application as list))
                set actInfo's name to act's name
                
                repeat with s in act's settings
                    set param to {|name|:missing value, |value|:missing value}
                    set param's |name| to s's name
                    set param's |value| to s's value
                    set end of actInfo's params to param
                end repeat
                
                set end of ll to actInfo
            end repeat
        end tell
    end tell
    return ll
end getWorkflowInfo

on join(sep, |list|)
    set od to AppleScript's text item delimiters
    set AppleScript's text item delimiters to sep
    set tmp to |list| as text
    set AppleScript's text item delimiters to od
    return tmp
end join