property theDeck : {}
property myHand : {}

createTheDeck()
newCards()
showCards()

-- creazione del mazzo di 52 carte
on createTheDeck()
     set theDeck to {}
     set theColors to {"Fiori", "Quadri", "Cuori", "Pique"}
     set hundreds to {100, 200, 300, 400}
     set highCards to {"J", "Q", "K", "A"}
     repeat with i from 1 to 4
          set theColor to item i of theColors
          set the100 to item i of hundreds
          repeat with i from 2 to 10
               set end of theDeck to {cNum: (the100 + i), cName:i, cColor:theColor, cValue:0}
          end repeat
          repeat with j from 1 to 4
               set highCard to item j of highCards
               set end of theDeck to {cNum: (the100 + 10 + j), cName:highCard, cColor:theColor, cValue:j}
          end repeat
     end repeat
end createTheDeck

-- Distribuzione di una mano di 13 carte
on newCards()
     set myHand to {}
     repeat 13 times
          set myCard to some item of theDeck
          set end of myHand to myCard
          cleanTheDeck(myCard)
     end repeat
end newCards

-- aggiornamento del mazzo, togliendo le carte distribuite
on cleanTheDeck(myCard)
     set newDeck to {}
     set theDeckRef to a reference to theDeck
     repeat with i from 1 to count of theDeckRef
          if item i of theDeckRef is not myCard then
               set end of newDeck to item i of theDeckRef
          end if
     end repeat
     set theDeck to newDeck
end cleanTheDeck

-- Mostra e valuta le carte della mano
on showCards()
     set myHandValue to 0
     set myCards to {}
     repeat with aCard in myHand
          set end of myCards to (cNum of aCard)
          set myHandValue to myHandValue + (cValue of aCard)
     end repeat
     
     -- Questo handler ordina myCards - grazie a "dant" (www.macscripter.net)
     set {saveDelims, text item delimiters} to {text item delimiters, ASCII character (10)}
     set x to do shell script "echo \"" & (myCards as text) & "\"|sort -rn"
     set text item delimiters to ASCII character (13)
     set myCards to text items of x
     repeat with i from 1 to count myCards
          set item i of myCards to (item i of myCards) as integer
     end repeat
     set text item delimiters to saveDelims
     
     ----- DISTRIBUZIONE / interessa solo per Bridge -----
     set {Piques, Cuori, Quadri, Fiori} to {0, 0, 0, 0}
     repeat with aCard in myCards
          if aCard > 400 then
               set Piques to Piques + 1
          else if aCard > 300 and aCard < 400 then
               set Cuori to Cuori + 1
          else if aCard > 200 and aCard < 300 then
               set Quadri to Quadri + 1
          else
               set Fiori to Fiori + 1
          end if
     end repeat
     set distribuzione to (Piques & "-" & Cuori & "-" & Quadri & "-" & Fiori) as string
     
     -- TEST / interessa solo per Bridge
     set cardDescription to ""
     repeat with k from 1 to count of myCards
          repeat with m from 1 to count of myHand
               if (item k of myCards) = (cNum of item m of myHand) then
                    set cardDescription to (cardDescription & (cName of item m of myHand) & "-" & (cColor of item m of myHand) & ", ") as string
                    exit repeat
               end if
          end repeat
     end repeat
     set cardDescription to (cardDescription & return & "Valore mano: " & myHandValue & return & "Distribuzione: " & distribuzione) as string
     display dialog cardDescription
     
end showCards